echo off
if exist pac_obj.dat goto INSTALL_DISK
if exist pac_obj.hdr goto INSTALL_DISK
if %1 .==. goto BAD_PARAMETER
if %1 == 1 goto OK
if %1 == 2 goto OK
if %1 == 3 goto OK
if %1 == 4 goto OK
goto BAD_PARAMETER
:OK
echo echo off >$#12345.bat
echo cls >>$#12345.bat
echo modemutl x %1 >>$#12345.bat
echo :START >>$#12345.bat
echo if exist RESTART.PRD del RESTART.PRD >>$#12345.bat
echo rs %%1 %%2  %%3 %%4 %%5 %%6 %%7 %%8 %%9 >>$#12345.bat
echo if exist RESTART.PRD goto START >>$#12345.bat
echo modemutl e %1 >>$#12345.bat
echo echo on >>$#12345.bat
copy prodigy.bat prod_bat.bak >NUL
copy $#12345.bat prodigy.bat >NUL
erase $#12345.bat
goto END
:INSTALL_DISK
echo ***************************************
echo * This program must be copied to your *
echo * hard drive or to Personal Disk A    *
echo * before use.  Copy it, then run it   *
echo * from there.                         *
echo *                                     *
echo * EXAMPLE:                            *
echo *  copy a:SETPORT.BAT c:\PRODIGY      *
echo ***************************************
goto END
:BAD_PARAMETER
echo ***************************************
echo * Please specify the number of the    *
echo * port you wish to setport when you   *
echo * use the service.  Use only 1, 2,    *
echo * 3, or 4.                            *
echo *                                     *
echo * EXAMPLE:                            *
echo *  setport 2                          *
echo ***************************************
:END
echo on
